\    File: UpDown.f
\  Author: Jeff Kelm
\ Created: 20-Nov-1998
\ Updated: 26-Jan-1999
\ Generic Up/Down control class

Comment:  Revision History (most recent first)
19990126
 - Changed Get/SetPosition: to Get/SetValue: to avoid name conflict
19981231
 - Incorporated the new ChildWindow class.
19981120
 - Created
Comment;



NEEDS BasicWin.f
CR .( Loading Up/Down control classes...)



:Class UpDownControl  <Super ChildWindow

   :M DefStyle: ( -- style)   \ default control style
      WS_CHILD WS_VISIBLE OR  WS_BORDER OR
      UDS_ARROWKEYS OR  UDS_SETBUDDYINT OR
      UDS_ALIGNRIGHT OR
      ;M

   :M DefClassName: ( -- ClassName)   \ default class name
      Z" msctls_updown32"
      ;M

   :M DefSize: ( -- cx cy)   \ default window size
      40 20
      ;M

   :M DefPosition: ( -- x y)   \ default window position
      0 0
      ;M

   :M SetBuddy: ( hBuddy)   \ assign buddy control
      0 SWAP UDM_SETBUDDY SendMessage: self  DROP
      ;M

   :M GetValue: ( -- n)   \ returns setting of up/down control
      0 0 UDM_GETPOS SendMessage: self
      word-split ABORT" Up/Down Control read error"
      ;M

   :M SetValue: ( n)   \ sets the up/down control position
      0 word-join 0 UDM_SETPOS SendMessage: self  DROP
      ;M

   :M SetDecimal: ( -- )   \ set display radix to decimal
      0 10 UDM_SETBASE SendMessage: self  DROP
      ;M

   :M SetHex: ( -- )   \ set display radix to hex
      0 16 UDM_SETBASE SendMessage: self  DROP
      ;M

   :M GetBase: ( -- n)   \ get current display radix
      0 0 UDM_GETBASE SendMessage: self
      ;M

    :M SetRange: ( lower upper)   \ set min & max limits
       MAKELONG 0 UDM_SETRANGE SendMessage: self  DROP
       ;M

    :M GetRange: ( -- lower upper)   \ retrieve min & max limits
        0 0 UDM_GETRANGE SendMessage: self word-split SWAP
        ;M

;Class