\    File: Trackbar.f
\  Author: Jeff Kelm
\ Created: 26-Oct-1998
\ Updated: 21-May-1999
\ Trackbar class

Comment:  Revision History (most recent first)
19990521
 - Cosmetic cleanup
19981231
 - Incorporated the new ChildWindow class.
19981204
 - Rename SetPosition:/GetPosition: to SetValue:/GetValue:
19981117
 - General cosmetic updates
 - redefined to use BaseWindow superclass and call BasicWin.f
Comment;



NEEDS BasicWin.f
CR .( Loading Trackbar class...)



\ \\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
\ \\\  A generic trackbar class
\
:Class Trackbar  <Super ChildWindow

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      ;M

   :M DefClassName: ( -- ClassName)   \ default class name
      Z" msctls_trackbar32"
      ;M

   \ how much the value changes for "line" up/down
   :M GetLineSize: ( -- n)
      0 0 TBM_GETLINESIZE SendMessage: self
      ;M

   \ sets how much the value changes for "line" up/down
   :M SetLineSize: ( n)
      0 TBM_SETLINESIZE SendMessage: self  DROP
      ;M

   \ how much the value changes for "page" up/down
   :M GetPageSize: ( -- n)
      0 0 TBM_GETPAGESIZE SendMessage: self
      ;M

   \ sets how much the value changes for "page" up/down
   :M SetPageSize: ( n)
      0 TBM_SETPAGESIZE SendMessage: self  DROP
      ;M

   :M GetValue: ( -- n)   \ gets current slider value
      0 0 TBM_GETPOS SendMessage: self
      ;M

   :M SetValue: ( n)   \ sets slider to value
      TRUE TBM_SETPOS SendMessage: self  DROP
      ;M

   :M GetRangeMax: ( -- n)
      0 0 TBM_GETRANGEMAX SendMessage: self
      ;M

   :M SetRangeMax: ( max f)   \ tf= redraw
      TBM_SETRANGEMAX SendMessage: self  DROP
      ;M

   :M GetRangeMin: ( -- n)
      0 0 TBM_GETRANGEMIN SendMessage: self
      ;M

   :M SetRangeMin: ( min f)   \ tf= redraw
      TBM_SETRANGEMIN SendMessage: self  DROP
      ;M

   :M GetSelEnd: ( -- n)
      0 0 TBM_GETSELEND SendMessage: self
      ;M

   :M SetSelEnd: ( end f)   \ tf=redraw
      TBM_SETSELEND SendMessage: self  DROP
      ;M

   :M GetSelStart: ( -- n)
      0 0 TBM_GETSELSTART SendMessage: self
      ;M

   :M SetSelStart: ( start f)   \ tf=redraw
      TBM_SETSELSTART SendMessage: self  DROP
      ;M

   \ retrieves the length of the slider in a trackbar
   :M GetThumbLength: ( -- n)
      0 0 TBM_GETTHUMBLENGTH SendMessage: self
      ;M

   \ sets the length of the slider in a trackbar
   :M SetThumbLength: ( n)
      0 SWAP TBM_SETTHUMBLENGTH SendMessage: self  DROP
      ;M

   \ retrieves the bounding rectangle for the trackbar's channel
   :M GetChannelRect: ( lpRect)
      0 TBM_GETCHANNELRECT SendMessage: self  DROP
      ;M

   \ retrieves the bounding rectangle for the slider
   :M GetThumbRect: ( lpRect)
      0 TBM_GETTHUMBRECT SendMessage: self  DROP
      ;M

   :M GetTick: ( iTic -- n)
      0 SWAP TBM_GETTIC SendMessage: self
      ;M

   :M SetTick: ( pos)
      0 TBM_SETTIC SendMessage: self  DROP
      ;M

   \ removes the current tick marks, tf=redraw
   :M ClearTicks: ( f -- )
      0 SWAP TBM_CLEARTICS SendMessage: self  DROP
      ;M

   :M GetTickPos: ( iTic -- n)   \ in client coordinates
      0 SWAP TBM_GETTICPOS SendMessage: self
      ;M

   :M GetTicksPtr: ( -- pointer)
      0 0 TBM_GETPTICS SendMessage: self
      ;M

   \ must have TBS_AUTOTICKS style set
   :M SetTickFreq: ( pos freq)
      TBM_SETTICFREQ SendMessage: self  DROP
      ;M

   :M GetNumTicks: ( -- n)
      0 0 TBM_GETNUMTICS SendMessage: self
      ;M

   :M SetRange: ( min max f)   \ tf= redraw
      >R word-join R> TBM_SETRANGE SendMessage: self  DROP
      ;M

   :M SetSel: ( min max f)   \ tf= redraw
      >R word-join R> TBM_SETSEL SendMessage: self  DROP
      ;M

   \ clears the current selection in a trackbar, tf=redraw
   :M ClearSel: ( f -- )
      0 SWAP TBM_CLEARSEL SendMessage: self  DROP
      ;M

;Class