\    File: Static.f
\  Author: Jeff Kelm
\ Created: 08-Dec-1998
\ Updated: 21-May-1999
\ Generic Static Window class

Comment:  Revision History (most recent first)
19990521
 - Cosmetic cleanup
19990224
 - Updated to include frame and rectangle styles
19981231
 - Incorporated the new ChildWindow class.
19981208
 - Created
Comment;



NEEDS BasicWin.f
CR .( Loading Static Window class...)


\ the base static control
:Class BaseStaticWindow  <Super ChildWindow

   :M DefClassName: ( -- ClassName)   \ default class name
      Z" STATIC"
      ;M

;Class



\ a simple static control for text
:Class StaticWindow  <Super BaseStaticWindow

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      SS_SIMPLE OR
      ;M

;Class



\ a text control w/o wordwrapping
:Class NoWrapTextbox  <Super BaseStaticWindow

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      SS_LEFTNOWORDWRAP OR
      ;M

;Class



\ a left-aligned text control
:Class LeftTextbox  <Super BaseStaticWindow

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      SS_LEFT OR
      ;M

;Class



\ a right-aligned text control
:Class RightTextbox  <Super BaseStaticWindow

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      SS_RIGHT OR
      ;M

;Class



\ a center-aligned text control
:Class CenterTextbox  <Super BaseStaticWindow

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      SS_CENTER OR
      ;M

;Class



\ a static control showing an image
:Class StaticImage   <Super BaseStaticWindow

   :M ImageType: ( -- ImageType)
      IMAGE_BITMAP
      ;M

   :M SetImage: ( hImage)
      ImageType: [ self ] STM_SETIMAGE SendMessage: self  DROP
      ;M

   :M GetImage: ( -- hImage)
      0 ImageType: [ self ] STM_GETIMAGE SendMessage: self
      ;M

;Class



\ a static control showing a bitmap
:Class StaticBitmap   <Super StaticImage

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      SS_BITMAP OR
      ;M

;Class



\ a static control showing an icon
:Class StaticIcon  <Super StaticImage

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      SS_ICON OR
      ;M

   :M ImageType: ( -- ImageType)
      IMAGE_ICON
      ;M

;Class



\ a static control showing a metafile
:Class StaticMetafile  <Super StaticImage

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      SS_ENHMETAFILE OR
      ;M

   :M ImageType: ( -- ImageType)
      IMAGE_ENHMETAFILE
      ;M

;Class



\ a static control showing a frame
:Class StaticFrame   <Super BaseStaticWindow

   \ rectangle in the window frame color (default is black)
   :M BlackRect:
      DefStyle: super  SS_BLACKRECT OR  SetStyle: self
      ;M

   \ rectangle in the screen background color (default is gray)
   :M GrayRect:
      DefStyle: super  SS_GRAYRECT OR  SetStyle: self
      ;M

   \ rectangle in the window background color (default is white)
   :M WhiteRect:
      DefStyle: super  SS_WHITERECT OR  SetStyle: self
      ;M

   \ frame in the window frame color (default is black)
   :M BlackFrame:
      DefStyle: super  SS_BLACKFRAME OR  SetStyle: self
      ;M

   \ frame in the screen background color (default is gray)
   :M GrayFrame:
      DefStyle: super  SS_GRAYFRAME OR  SetStyle: self
      ;M

   \ frame in the window background color (default is white)
   :M WhiteFrame:
      DefStyle: super  SS_WHITEFRAME OR  SetStyle: self
      ;M

   \ draws an etched frame (frame appears lower than background)
   :M EtchedFrame:
      DefStyle: super  SS_ETCHEDFRAME OR  SetStyle: self
      ;M

   \ draws frame with half-sunken border
   :M SunkenFrame:
      DefStyle: super  SS_SUNKEN OR  SetStyle: self
      ;M

;Class