\    File: Progbar.f
\  Author: Jeff Kelm
\ Created: 30-Oct-1998
\ Updated: 21-May 1999
\ Generic Progress bar class

Comment:  Revision History (most recent first)
19990521
 - Cosmetic cleanup
19990423
 - Added SmoothProgressbar class to eliminate segmented bar.
19981231
 - Incorporated the new ChildWindow class.
19981216
 - Rename DeltaPosition: to +Value: for consistency with
   Get/SetValue:
19981202
 - Rename Get/SetPosition: to Get/SetValue: to avoid conflict
   with window position methods
19981117
 - General cosmetic updates
 - redefined to use BaseWindow superclass and call BasicWin.f
Comment;



NEEDS BasicWin.f
CR .( Loading Progress Bar class...)



:Class Progressbar  <Super ChildWindow

   :M DefClassName: ( -- ClassName)   \ default class name
      Z" msctls_progress32"
      ;M

   :M +Value: ( n)   \ increases the value of progress bar
                     \ by specified increment
      0 SWAP PBM_DELTAPOS SendMessage: self  DROP
      ;M

   :M GetValue: ( -- n)   \ returns the current position value
      0 0 PBM_DELTAPOS SendMessage: self
      ;M

   :M SetValue: ( n)   \ sets the current position value
      0 SWAP PBM_SETPOS SendMessage: self  DROP
      ;M

   :M SetRange: ( min max)   \ sets the minimum and maximum
                             \ values for progress bar
      word-join 0 PBM_SETRANGE SendMessage: self  ?WinError
      ;M

   :M SetStep: ( n)   \ sets the step increment
      0 SWAP PBM_SETSTEP SendMessage: self  DROP
      ;M

   :M GetStep: ( -- n)   \ returns the current step increment
      0 0 PBM_SETSTEP SendMessage: self
      DUP SetStep: self
      ;M

   :M StepIt: ( -- )   \ advances the current position by the
                       \ step increment
      0 0 PBM_STEPIT SendMessage: self  DROP
      ;M

;Class



:Class SmoothProgressbar  <Super Progressbar

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      \ has to be done at creation time, doesn't work if added
      \ afterward (e.g., +Style:)
      PBS_SMOOTH OR
      ;M

;Class