\    File: Buttons.f
\  Author: Jeff Kelm
\ Created: 17-Nov-1998
\ Updated: 21-May-1999
\ Generic Button classes

Comment:  Revision History (most recent first)
19990521
 - Removed DefStyle: from BaseButton (handled in ChildWindow).
 - Cosmetic cleanup
19981231
 - Incorporated the new ChildWindow class..
 - added GetImage: methods to IconButton and BitmapButton.
19981216
 - Removed SetText: method, now handled by SetText: in
   BasicWin.f.
19981120
 - Changed  'DefStyle: self'  to  'DefStyle: [ self ]' in
   Create: method so style will inherit properly.
 - Added Bitmap and Icon button classes.
 - Added BS_AUTORADIOBUTTON and BS_AUTOCHECKBOX to default
   styles.
19981117
 - Created
Comment;



NEEDS BasicWin.f
CR .( Loading Button classes...)



\ ======================
\ Common Control Buttons
\ ======================

:Class BaseButton  <Super ChildWindow

   :M DefClassName: ( -- ClassName)   \ default class name
      Z" BUTTON"
      ;M

   :M DefSize: ( -- cx cy)   \ default window size
      72 24
      ;M

   :M DefPosition: ( -- x y)   \ default window position
      50 50
      ;M

;Class



\ =====================
\ A standard pushbutton
\ =====================

:Class PushButton  <Super BaseButton

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      BS_PUSHBUTTON OR  BS_CENTER OR
      ;M

;Class



\ ====================================
\ A "default" (dark border) pushbutton
\ ====================================

:Class DefPushButton  <Super BaseButton

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      BS_DEFPUSHBUTTON OR  BS_CENTER OR
      ;M

;Class



\ ==========
\ A checkbox
\ ==========

:Class CheckBox  <Super BaseButton

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      BS_AUTOCHECKBOX OR  BS_CENTER OR
      ;M

;Class



\ ==============
\ A radio button
\ ==============

:Class RadioButton  <Super BaseButton

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      BS_AUTORADIOBUTTON OR  BS_CENTER OR
      ;M

;Class



\ =========================================
\ A group box (outline with optional title)
\ =========================================

:Class GroupBox  <Super BaseButton

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      BS_GROUPBOX OR  BS_CENTER OR
      ;M

;Class



\ ===============
\ A Bitmap button
\ ===============

:Class BitmapButton  <Super BaseButton

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      BS_BITMAP OR  BS_CENTER OR
      ;M

   :M SetImage: ( hBmp)   \ set the bitmap image to use with
                          \ the button
      IMAGE_BITMAP BM_SETIMAGE SendMessage: self  DROP
      ;M

   :M GetImage: ( -- hBmp)   \ get the bitmap image used with
                             \ the button
      0 IMAGE_BITMAP BM_GETIMAGE SendMessage: self
      ;M

;Class



\ ==============
\ An Icon button
\ ==============

:Class IconButton  <Super BaseButton

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      BS_ICON OR  BS_CENTER OR
      ;M

   :M SetImage: ( hIcon)   \ set the icon image to use with
                           \ the button
      IMAGE_ICON BM_SETIMAGE SendMessage: self  DROP
      ;M

   :M GetImage: ( -- hIcon)   \ get the icon image used with
                              \ the button
      0 IMAGE_ICON BM_GETIMAGE SendMessage: self
      ;M

;Class