\    File: Trackbar.f
\  Author: Jeff Kelm
\ Created: 26-Oct-1998
\ Updated: 31-Dec-1998
\ Trackbar class



NEEDS BasicWin.f
CR .( Loading Trackbar class...)



\ \\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
\ \\\  A generic trackbar class
\
:Class Trackbar  <Super ChildWindow

:M DefStyle: ( -- style)   \ default control style
   DefStyle: super
   ;M

:M DefClassName: ( -- ClassName)   \ default class name
   Z" msctls_trackbar32"
   ;M

:M GetLineSize: ( -- n)   \ how much the value changes for "line" up/down
   0 0 TBM_GETLINESIZE SendMessage: self
   ;M

:M SetLineSize: ( n)   \ sets how much the value changes for "line" up/down
   0 TBM_SETLINESIZE SendMessage: self  DROP
   ;M

:M GetPageSize: ( -- n)   \ how much the value changes for "page" up/down
   0 0 TBM_GETPAGESIZE SendMessage: self
   ;M

:M SetPageSize: ( n)   \ sets how much the value changes for "page" up/down
   0 TBM_SETPAGESIZE SendMessage: self  DROP
   ;M

:M GetValue: ( -- n)   \ gets current slider value
   0 0 TBM_GETPOS SendMessage: self
   ;M

:M SetValue: ( n)   \ sets slider to value
   TRUE TBM_SETPOS SendMessage: self  DROP
   ;M

:M GetRangeMax: ( -- n)
   0 0 TBM_GETRANGEMAX SendMessage: self
   ;M

:M SetRangeMax: ( max f)   \ tf= redraw
   TBM_SETRANGEMAX SendMessage: self  DROP
   ;M

:M GetRangeMin: ( -- n)
   0 0 TBM_GETRANGEMIN SendMessage: self
   ;M

:M SetRangeMin: ( min f)   \ tf= redraw
   TBM_SETRANGEMIN SendMessage: self  DROP
   ;M

:M GetSelEnd: ( -- n)
   0 0 TBM_GETSELEND SendMessage: self
   ;M

:M SetSelEnd: ( end f)   \ tf=redraw
   TBM_SETSELEND SendMessage: self  DROP
   ;M

:M GetSelStart: ( -- n)
   0 0 TBM_GETSELSTART SendMessage: self
   ;M

:M SetSelStart: ( start f)   \ tf=redraw
   TBM_SETSELSTART SendMessage: self  DROP
   ;M

:M GetThumbLength: ( -- n)   \ retrieves the length of the slider in a trackbar
   0 0 TBM_GETTHUMBLENGTH SendMessage: self
   ;M

:M SetThumbLength: ( n)   \ sets the length of the slider in a trackbar
   0 SWAP TBM_SETTHUMBLENGTH SendMessage: self  DROP
   ;M

\ retrieves the size and position of the bounding rectangle
\ for the trackbar's channel
:M GetChannelRect: ( lpRect)   \ retrieves the bounding rectangle for the trackbar's channel
   0 TBM_GETCHANNELRECT SendMessage: self  DROP
   ;M

:M GetThumbRect: ( lpRect)   \ retrieves the bounding rectangle for the slider
   0 TBM_GETTHUMBRECT SendMessage: self  DROP
   ;M

:M GetTick: ( iTic -- n)
   0 SWAP TBM_GETTIC SendMessage: self
   ;M

:M SetTick: ( pos)
   0 TBM_SETTIC SendMessage: self  DROP
   ;M

:M ClearTicks: ( f -- )   \ removes the current tick marks, tf=redraw
   0 SWAP TBM_CLEARTICS SendMessage: self  DROP
   ;M

:M GetTickPos: ( iTic -- n)   \ in client coordinates
   0 SWAP TBM_GETTICPOS SendMessage: self
   ;M

:M GetTicksPtr: ( -- pointer)
   0 0 TBM_GETPTICS SendMessage: self
   ;M

:M SetTickFreq: ( pos freq)   \ must have TBS_AUTOTICKS style set
   TBM_SETTICFREQ SendMessage: self  DROP
   ;M

:M GetNumTicks: ( -- n)
   0 0 TBM_GETNUMTICS SendMessage: self
   ;M

:M SetRange: ( min max f)   \ tf= redraw
   >R word-join R> TBM_SETRANGE SendMessage: self  DROP
   ;M

:M SetSel: ( min max f)   \ tf= redraw
   >R word-join R> TBM_SETSEL SendMessage: self  DROP
   ;M

:M ClearSel: ( f -- )   \ clears the current selection in a trackbar, tf=redraw
   0 SWAP TBM_CLEARSEL SendMessage: self  DROP
   ;M

;Class