\    File: Static.f
\  Author: Jeff Kelm
\ Created: 08-Dec-1998
\ Updated: 24-Feb-1999
\ Generic Static Window class



NEEDS BasicWin.f
CR .( Loading Static Window class...)



:Class BaseStaticWindow  <Super ChildWindow   \ the base static control

   :M DefClassName: ( -- ClassName)   \ default class name
      Z" STATIC"
      ;M

;Class



:Class StaticWindow  <Super BaseStaticWindow      \ a simple static control for text

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      SS_SIMPLE OR
      ;M

;Class



:Class NoWrapTextbox  <Super BaseStaticWindow   \ a text control w/o wordwrapping

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      SS_LEFTNOWORDWRAP OR
      ;M

;Class



:Class LeftTextbox  <Super BaseStaticWindow   \ a left-aligned text control

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      SS_LEFT OR
      ;M

;Class



:Class RightTextbox  <Super BaseStaticWindow   \ a right-aligned text control

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      SS_RIGHT OR
      ;M

;Class



:Class CenterTextbox  <Super BaseStaticWindow   \ a center-aligned text control

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      SS_CENTER OR
      ;M

;Class



:Class StaticImage   <Super BaseStaticWindow   \ a static control showing an image

   :M ImageType: ( -- ImageType)
      IMAGE_BITMAP
      ;M

   :M SetImage: ( hImage)
      ImageType: [ self ] STM_SETIMAGE SendMessage: self  DROP
      ;M

   :M GetImage: ( -- hImage)
      0 ImageType: [ self ] STM_GETIMAGE SendMessage: self
      ;M

;Class



:Class StaticBitmap   <Super StaticImage   \ a static control showing a bitmap

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      SS_BITMAP OR
      ;M

;Class



:Class StaticIcon  <Super StaticImage   \ a static control showing an icon

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      SS_ICON OR
      ;M

   :M ImageType: ( -- ImageType)
      IMAGE_ICON
      ;M

;Class



:Class StaticMetafile  <Super StaticImage   \ a static control showing a metafile

   :M DefStyle: ( -- style)   \ default control style
      DefStyle: super
      SS_ENHMETAFILE OR
      ;M

   :M ImageType: ( -- ImageType)
      IMAGE_ENHMETAFILE
      ;M

;Class



:Class StaticFrame   <Super BaseStaticWindow   \ a static control showing a frame

   :M BlackRect:   \ rectangle in the window frame color (default is black)
      DefStyle: super  SS_BLACKRECT OR  SetStyle: self
      ;M

   :M GrayRect:   \ rectangle in the screen background color (default is gray)
      DefStyle: super  SS_GRAYRECT OR  SetStyle: self
      ;M

   :M WhiteRect:   \ rectangle in the window background color (default is white)
      DefStyle: super  SS_WHITERECT OR  SetStyle: self
      ;M

   :M BlackFrame:   \ frame in the window frame color (default is black)
      DefStyle: super  SS_BLACKFRAME OR  SetStyle: self
      ;M

   :M GrayFrame:   \ frame in the screen background color (default is gray)
      DefStyle: super  SS_GRAYFRAME OR  SetStyle: self
      ;M

   :M WhiteFrame:   \ frame in the window background color (default is white)
      DefStyle: super  SS_WHITEFRAME OR  SetStyle: self
      ;M

   :M EtchedFrame:   \ draws an etched frame (frame appears lower than background)
      DefStyle: super  SS_ETCHEDFRAME OR  SetStyle: self
      ;M

   :M SunkenFrame:   \ draws frame with half-sunken border
      DefStyle: super  SS_SUNKEN OR  SetStyle: self
      ;M

;Class