\    File: Progbar.f
\  Author: Jeff Kelm
\ Created: 30-Oct-1998
\ Updated: 31-Dec-1998
\ Generic Progress bar class



NEEDS BasicWin.f
CR .( Loading Progress Bar class...)



:Class Progressbar  <Super ChildWindow

   :M DefClassName: ( -- ClassName)   \ default class name
      Z" msctls_progress32"
      ;M

:M +Value: ( n)   \ increases the value of progress bar by specified increment
   0 SWAP PBM_DELTAPOS SendMessage: self  DROP
   ;M

:M GetValue: ( -- n)   \ returns the current position value
   0 0 PBM_DELTAPOS SendMessage: self
   ;M

:M SetValue: ( n)   \ sets the current position value
   0 SWAP PBM_SETPOS SendMessage: self  DROP
   ;M

:M SetRange: ( min max)   \ sets the minimum and maximum values for progress bar
   word-join 0 PBM_SETRANGE SendMessage: self  ?WinError
   ;M

:M SetStep: ( n)   \ sets the step increment
   0 SWAP PBM_SETSTEP SendMessage: self  DROP
   ;M

:M GetStep: ( -- n)   \ returns the current step increment
   0 0 PBM_SETSTEP SendMessage: self
   DUP SetStep: self
   ;M

:M StepIt: ( -- )   \ advances the current position by the step increment
   0 0 PBM_STEPIT SendMessage: self  DROP
   ;M

;Class